;
; Script-файл для соединения RUSNet удаленного доступа к сети
; (c) 2008, ЗАО "НПО РУСНЕТ"
; главная процедура (должна присутствовать всегда)
;
proc main
;
; Определения переменных
;
integer intCount = 0 ; счетчик попыток получения доступа к серверу
integer intTries = 3 ; кол-во попыток получения доступа к серверу
string strUser = "ername: " ; приглашение на ввод имени пользователя
string strPasswd = "ssword: " ; приглашение на ввод пароля
string strAnnex = "annex: " ; подсказка комамндной строки терминального сервера
string strPPPcmd = "ppp^M" ; команда запуска протокола PPP
;
; ожидание 3 сек. и посылка кода ENTER
;
delay 3
transmit "^M"
;
; передача имени пользователя
;
while intCount < intTries do
waitfor strUser until 10 ; ожидание подсказки "...ername: "
if $SUCCESS then
transmit $USERID, raw ; передача имени пользователя
transmit "^M"
goto putPasswd
endif
intCount = intCount + 1 ; повторение попытки в случае неуспеха
endwhile
goto FailPoint ; переход на режим ввода с клавиатуры

putPasswd:
;
; передача пароля
;
intCount = 0
while intCount < intTries do
waitfor strPasswd until 10 ; ожидание подсказки "...assword: "
if $SUCCESS then
transmit $PASSWORD, raw ; передача пароля
transmit "^M"
goto putCmd
endif
intCount = intCount + 1 ; повторение попытки в случае неуспеха
endwhile
goto FailPoint ; переход на режим ввода с клавиатуры

putCmd:
;
; запуск протокола PPP
;
intCount = 0
while intCount < intTries do
waitfor strAnnex until 10 ; ожидание подсказки сервера "...annex: "
if $SUCCESS then
transmit strPPPcmd ; передача команды запуска PPP протокола
goto Done
endif
intCount = intCount + 1
endwhile

FailPoint:
;
; переход на режим ввода с клавиатуры
;
set screen keyboard on
halt

Done:
;
; завершение диалога с сервером
;
endproc